Fonction GetRemoteFile

Bonjour,

Dans un outil VBA pour Autocad je souhaite utiliser la fonction GetRemoteFile :

Public Const SSITE = "http://sites.google.com/site/emethodes/home/outils-pour-autocad/trace-banches-courbes/"
Dim sFile As String
Dim sChem As String
sChem = SSITE + "CCRV.DWG"
ThisDrawing.Utility.GetRemoteFile sChem, sFile, True

Tout se passe bien sauf que le fichier DWG téléchargé n'est pas le plan attendu : c'est une boite de dialogue en HTML dont je n'ai que faire.

Avez vous déjà réussit à résoudre ce problème d'une manière ou d'une autre ?

Merci pour vos réponses.

Bonjour à toutes et tous,

Pas de spécialiste VBA encore sur ce forum ?

Dommage,... [Vous devez être inscrit et connecté pour voir cette image]

Salut

Voici deux réponse en lisp/vlisp

En utilisant GetRemoteFile

Code:

(defun telecharger(lien rep / cp ok tmp util)
  (setq util (vla-get-Utility (vla-get-ActiveDocument (vlax-get-acad-object))))
  (if (eq (vla-isurl util lien) :vlax-true)
    (if (vl-catch-all-error-p (vl-catch-all-apply 'vla-GetRemoteFile (list util lien 'tmp :vlax-true)))
      (princ "\nErreur lors du téléchargement.")
      (progn
    (setq cp (strcat rep (vl-filename-base lien) (vl-filename-extension lien)))
    (if (findfile cp)
      (vl-file-delete cp)
    )
    (if (vl-catch-all-error-p (vl-catch-all-apply 'vl-file-copy (list tmp cp)))
      (progn
          (princ "\nImpossible de déplacer le fichier \""
          (strcat (vl-filename-base cp)(vl-filename-extension cp))
          "\" depuis le répertoire \n\""
          tmp
        )
        (vl-file-delete tmp)
      )
      (progn
        (vl-file-delete tmp)
            (if (zerop (vl-file-size cp))
              (progn
        (vl-file-delete cp)
        (princ "\nImpossible de télécharger le fichier.")
          )
          (setq ok T)
        )
      )
    )
      )
    )
    (princ "\nLe lien n'est pas valide.")
  )
  ok

Une autre plus complète appelant les activex

Code:

(defun download (url dir / byte fic file fso http ok tbl taille)
  (setq http (vlax-create-object "MSXML2.XMLHTTP")
        fso  (vlax-create-object "scripting.FileSystemObject")
    file (strcat dir (vl-filename-base url) (vl-filename-extension url)))
  (vlax-invoke-method http 'open "get" url :vlax-false)
  (if (vl-catch-all-error-p (vl-catch-all-apply 'vlax-invoke (list http 'send)))
    (princ (strcat "\nLe lien " url " n'est pas valide."))
    (if (eq (vlax-get http 'status) 200)
      (if (vl-catch-all-error-p (setq taille (vl-catch-all-apply 'vlax-invoke (list http 'getResponseHeader "Content-Length"))))
    (princ "\nErreur de lecture sur la taille du fichier.")
        (if (< (atoi taille) (vlax-get (vlax-invoke fso 'getdrive (substr (vlax-invoke fso 'getabsolutepathname file) 1 1)) 'freespace))
      (progn
        (princ "\nTéléchargement en cours...")(princ)
        (while (not (eq (vlax-get http 'readystate) 4))
          (vla-eval (vlax-get-acad-object) "DoEvents")
        )
        (setq tbl (vlax-safearray->list (vlax-variant-value (vlax-get-property http 'responsebody))))
        (if (vl-catch-all-error-p (setq fic (vl-catch-all-apply 'vlax-invoke (list fso 'createtextfile file))))
          (princ (strcat "\nImpossible de créer le fichier " file))
          (progn
        (foreach byte tbl
          (vlax-invoke fic 'write (vl-list->string (list byte)))
        )
        (vlax-invoke fic 'close)
        (setq ok T)
          )
        )
      )
    )
      )
      (princ (strcat "\n" (vlax-get http 'statustext) "...Erreur " (itoa (vlax-get http 'status)) "."))
    )
  )
  (vlax-release-object http)
  (vlax-release-object fso)
  ok
)

@+

Bonsoir à toutes et tous,

Heu, et ça sert à quoi exactement de faire ça ?

Merci d'avance,

PS: Tu vois Patrick_35 qu'il y a des débutants ici (je parle de moi, bien entendu,... [Vous devez être inscrit et connecté pour voir cette image] )

Salut lili

PS: Tu vois Patrick_35 qu'il y a des débutants ici (je
parle de moi, bien entendu,... [Vous devez être inscrit et connecté pour voir cette image] )

Cela veut dire que tu commences à tâter à la programmation [Vous devez être inscrit et connecté pour voir cette image]

Heu, et ça sert à quoi exactement de faire ça ?

A télécharger un lien depuis autocad. Par exemple pour une mise à jour automatique.

@+

Re,

Cela veut dire que tu commences à tâter à la programmation [Vous devez être inscrit et connecté pour voir cette image]

Ben non, toujours pas comme je le souhaiterai,...

Ok pour la réponse,

Merci [Vous devez être inscrit et connecté pour voir ce lien], [Vous devez être inscrit et connecté pour voir cette image]

Bonjour,

Et merci Patrick_35, ça marche effectivement en VL.........Et j'ai réessayé avec VBA et ça marche aussi, avec un code inchangé par rapport aux essais infructueux réalisés précédemment.....j'ai cherché partout....c'est bien rare d'être embêté parce-qu'une fonction fonctionne.....une voiture avec des lumières bleues et des gens très gentils en blanc m'attendent devant la porte...je crois que je vais y aller pour essayer cette joli veste avec les manches qui s'accroche dans le dos....

Tu as peut-être une variable qui à perturbé ton fonctionnement.
Une fois le pc éteint et le prog relancé, des miracles se font ^^

Je souhaite qu'il te shoot pas trop avec les médocs tes petits hommes blancs.

@+